Question : roaming profiles windows xp pro

Hi Folks,

Had one windows XP pro workstation with 4 users configured (with that login splash screen where you click the profile to log in.

Now i have installed a new win XP pro, and hope i can now use all the existing profile setting on the original computer in situ.

In other words, i would like user profiles on the new computer to be loaded from the original - desktop, my docs, and outlook mail files all loaded from the current location on the orignal computer over the network.

I also have a windows 2003 server available on my home network if absolutely necessary, but as it is earmarked already for a different (importnat ;-) purpose, i'd like to try to avoid using it for this job if poss.

Any suggestions as to how i can go about acheiving my goal? :-)

Thanks and regards,  Mike.

Answer : roaming profiles windows xp pro

Ho hum.. and I still managed to post typos

Corrected version of Logoff Script

' Logoff Script (Copies Profile to the Server)

Const DRIVE = "s:"
Const PROFILESTORE = "\\Server\Share"

' If you need authentication to map to the drive...

Const USERNAME = "SomeDomain\SomeUser"
Const PASSWORD = "Password"

Set objShell = CreateObject("WScript.Shell")
Set objFileSystem = CreateObject("Scripting.FileSystemObject")
Set objNetwork = CreateObject("WScript.Network")

' Retrieve the User Profile Path

Set objEnvVar = objShell.Environment("process")
strProfilePath = objEnvVar("USERPROFILE") & "\"
strUserName = objEnVar("USERNAME")

' Map the Temporary drive to the store

objNetwork.MapNetworkDrive DRIVE, PROFILESTORE, , USERNAME, PASSWORD

' Check connection to the Profile Store

strProfileStore = DRIVE & "\" & strUserName & "\"

If objFileSystem.FolderExists(strProfileStore) Then
      Set objProfileFolder = objFileSystem.GetFolder(strProfilePath)
Else
      wscript.echo "Error connecting to the Profile Store"
      wscript.quit
End If

For Each objFile in objProfileFolder.Files      
      If (InStr(LCase(objFile.Name), "ntuser") = 0) Then
            objFile.Copy strProfileStore, True
      End If
Next

For Each objSubFolder in objProfileFolder.SubFolders
      If (LCase(objSubFolder.Name) <> "local settings") Then
            objSubFolder.Copy strProfileStore, True
      End If
Next

Set objProfileFolder = Nothing

' Disconnect Temporary Network Drive

objNetwork.RemoveNetworkDrive DRIVE